metóda top:

medzi metódy na prácu so zásobníkom pridáme novú funkciu top, ktorá vráti hodnotu na vrchu zásobníka, pričom v zásobníku ju ponechá

type
  TPrvok = char;
  TStack = class
    st:array of TPrvok;
    constructor Create;
    procedure push(p:TPrvok);
    procedure pop(var p:TPrvok);
    function top:TPrvok;
    function empty:boolean;
  end;
...
function stack.top:TPrvok;
begin
  if empty then chyba('Prázdny zásobník');
  Result:=st[High(st)];
end;

najprv len a, potom rovnaký počet len b:

aⁿbⁿ, 0<=n

function test(var t:TextFile):boolean;
var
  s:TStack;
  c:char;
begin
  s:=TStack.Create;
  read(t,c);
  while c='a' do begin
    s.push(c); read(t,c);
  end;
  while (c='b') and not s.empty do begin
    s.pop(c); read(t,c);
  end;
  Result:=(c=#13) and s.empty;
  s.Free;
end;

najprv len a, potom rovnaký alebo väčší počet b:

aⁿb^m, 0<=n<=m

function test(var t:TextFile):boolean;
var
  s:TStack;
  c:char;
begin
  s:=TStack.Create;
  read(t,c);
  while c='a' do begin
    s.push(c); read(t,c);
  end;
  while c='b' do begin
    if not s.empty then s.pop(c);
    read(t,c);
  end;
  Result:=(c=#13) and s.empty;
  s.Free;
end;

je palindrom:

wcw^r

kde w je z abecedy {a,b}

w^r je zrkadlový obraz slova w

function test(var t:TextFile):boolean;
var
  s:TStack;
  c:char;
begin
  s:=TStack.Create;
  read(t,c);
  while c in ['a','b'] do begin
    s.push(c); read(t,c);
  end;
  if c='c' then begin
    read(t,c);
    while not s.empty and (c=s.top) do begin
      s.pop(c); read(t,c);
    end;
    Result:=(c=#13) and s.empty;
  end
  else Result:=false;
  s.Free;
end;

rovnaký počet a a b:

#a = #b, rovnaký počet a-čok aj b-čok

function test(var t:TextFile):boolean;
var
  s:TStack;
  c:char;
begin
  s:=TStack.Create;
  read(t,c);
  while c in ['a','b'] do begin
    if s.empty or (c=s.top) then s.push(c)
    else s.pop(c);
    read(t,c);
  end;
  Result:=(c=#13) and s.empty;
  s.Free;
end;

rovnaký počet a, b a c:

logická funkciu abc, ktorá vráti true, ak je vo vstupnom riadku rovnaký počet a-čok, b-čok a c-čok

využite dve inštancie TStack

okrem dvoch zásobníkov môžete použiť už len jednu znakovú pomocnú premennú

function abc(var t:TextFile):boolean;
var
  s1,s2:TStack;
  c:char;
begin
  s1:=TStack.Create; s2:=TStack.Create;
  read(t,c);
  while c in ['a','b','c'] do begin
    case c of
     'a':
       begin
        if s1.empty or ('a'=s1.top) then s1.push('a')
        else s1.pop(c);
        if s2.empty or ('a'=s2.top) then s2.push('a')
        else s2.pop(c);
       end;
     'b':
       if s1.empty or ('b'=s1.top) then s1.push('b')
       else s1.pop(c);
     'c':
       if s2.empty or ('c'=s2.top) then s2.push('c')
       else s2.pop(c);
    end;
    read(t,c);
  end;
  Result:=(c=#13) and s1.empty and s2.empty;
  s1.Free; s2.Free;
end;

vyhoď všetky nulové prvky:

pomocou pomocného zásobníka spracujte čísla v zásobníku tak, že vyhádžete všetky nulové prvky

procedure vyhod0(s:TStack);
var
  p:TStack;
  i:integer;
begin
  p:=TStack.Create;
  while not s.empty do begin
    s.pop(i);
    if i<>0 then p.push(i);
  end;
  while not p.empty do begin
    p.pop(i); s.push(i);
  end;
  p.Free;
end;

nulové prvky zásobníka na spodok:

pomocou pomocného zásobníka spracujte čísla v zásobníku tak, že všetky nulové prvky premiestnite na spodok zásobníka

procedure presun0(s:TStack);
var
  p:TStack;
  i,j:integer;
begin
  p:=TStack.Create; j:=0;
  while not s.empty do begin
    s.pop(i);
    if i<>0 then p.push(i)
    else inc(j);
  end;
  while j>0 do begin
    s.push(0); dec(j);
  end;
  while not p.empty do begin
    p.pop(i); s.push(i);
  end;
  p.Free;
end;

postfixový zápis:

7 4 * 9 2 4 - * 6 / +

• vyhodnoťte
• prepíšte do infixu a prefixu

7 4 * 9 2 4 - * 6 / +
(7 4 *) 9 (2 4 -) * 6 / +
(7 4 *) (9 (2 4 -) *) 6 / +
(7 4 *) ((9 (2 4 -) *) 6 /) +
(7 * 4) + ((9 * (2 - 4)) / 6) = 25   ... infix
+ (* 7 4) (/ (* 9 (- 2 4)) 6)
+ * 7 4 / * 9 - 2 4 6 ... prefix

prefixový tvar:

+ * - + 1 2 3 4 * 5 - 6 + 7 8

• prepíšte do infixu a postfixu
• vyhodnoťte

+ * - + 1 2 3 4 * 5 - 6 + 7 8
+ (* (- (+ 1 2) 3) 4) (* 5 (- 6 (+ 7 8)))
(((1 + 2) - 3) * 4) + (5 * (6 - (7 + 8)))
(((1 2 +) 3 -) 4 *) (5 (6 (7 8 +) -) *) +
1 2 + 3 - 4 * 5 6 7 8 + - * +
= 45

infixový zápis:

3*(4+5)-6*7/(8+6)

• prepíšte do prefixu a postfixu

3*(4+5)-6*7/(8+6)

(3 * (4 + 5)) - ((6 * 7) / (8 + 6))
- (* 3 (+ 4 5)) (/ (* 6 7) (+ 8 6))
- * 3 + 4 5 / * 6 7 + 8 6
(3 (4 5 +) *) ((6 7 *) (8 6 +) /) -
3 4 5 + * 6 7 * 8 6 + / -